{smcl}
{* *! version 1.0  22sept2009}{...}
{cmd:help asignadip, help asignadipi} {right: version 1.0}
{hline}


{title:Title}

{p 8 14 2}
{hi:asignadip} {hline 2}Calcula la composici{c o'}n de la C{c a'}mara de Diputados en M{c e'}xico.


{title:Syntax}

{pstd}Asignaci{c o'}n de curules a partir de una base de datos:

{p 8 17 2}
{cmdab:asigna:dip}
{varlist}
{ifin}
[{cmd:,} {it:options}]


{pstd}Asignaci{c o'}n de curules a partir de argumentos (forma inmediata de {cmd:asignadip}; 
ver {helpb immed}):

{p 8 17 2}
{cmdab:asignadipi}
{it: namelist}
[{cmd:,}
{it:asignadipi_options}]



{synoptset 18 tabbed}{...}
{synopthdr}
{synoptline}
{syntab:Main}
{synopt:{opt nulo:ynoreg(vars)}}variable(s) que contienen los porcentajes de votos nulos y para candidatos no registrados{p_end}
{synopt:{opt thr:eshold(#)}}umbral # de representaci{c o'}n para tener derecho a participar en la asignaci{c o'}n de curules plurinominales; 
default es {cmd:threshold(.02)}{p_end}
{synopt:{opt esc:rp(#)}}n{c u'}mero {it:#} de curules plurinominales; 
default es {cmd:escrp(200)}{p_end}
{synopt:{opt nomay}}suprime el componente de mayor{c i'}a relativa en la asignaci{c o'}n de curules{p_end}
{synopt:{opt norp}}suprime el componente de representaci{c o'}n proporcional en la asignaci{c o'}n de curules{p_end}
{synopt:{opt noprint}}sumprime la tabla de resultados{p_end}
{syntab:Advanced}
{synopt:{opt maxs:eats(#)}}n{c u'}mero # m{c a'}ximo de curules en la C{c a'}mara de Diputados a los que pueden tener derecho los partidos pol{c i'}ticos; 
default es {cmd:maxseats(300)}{p_end}
{synopt:{opt maxover:rep(#)}}porcentaje # m{c a'}ximo de curules que puede tener un partido con respecto a su porcentaje de votaci{c o'}n nacional emitida; 
default es {cmd:maxoverrep(.08)}{p_end}
{synopt:{opth numm:ay(numlist)}}instruye a {cmd:asignadip} para que utilice {it: numlist} como el n{c u'}mero de curules de mayor{c i'}a relativa para cada partido en {varlist}, 
en lugar de calcularlos a partir de la base de datos{p_end}
{synopt:{opt maxi:ter(#)}}n{c u'}mero # m{c a'}ximo de iteraciones en la asignaci{c o'}n de curules plurinominales cuando alg{c u'}n partido se encuentra en los supuestos de sobrerrepresentaci{c o'}n;
default es {cmd:maxiter(20)}{p_end}
{synoptline}
{p2colreset}{...}
{p 4 6 2}
{cmd:by} is allowed with {cmd:asignadip}; see {manhelp by D}.
{p_end}



{synoptset 18 tabbed}{...}
{synopthdr:asignadipi_options}
{synoptline}
{synopt:{opt numm:ay(numlist)}}n{c u'}mero de curules de mayor{c i'}a relativa para cada partido en {it: namelist}{p_end}
{p2coldent:* {opth perc:rp(numlist)}}porcentaje de votaci{c o'}n de cada partido en {it: namelist}{p_end}
{synopt:{opt esc:rp(#)}}numero {it:#} de curules en el componente de representaci{c o'}n proporcional; default es {cmd:escrp(200)}{p_end}
{synopt:{opt thr:eshold(#)}}umbral # de representaci{c o'}n para tener derecho a participar en la asignaci{c o'}n de curules plurinominales; 
default es {cmd:threshold(.02)}{p_end}
{synopt:{opt maxs:eats(#)}}n{c u'}mero # m{c a'}ximo de curules en la C{c a'}mara de Diputados a los que pueden tener derecho los partidos pol{c i'}ticos; 
default es {cmd:maxseats(300)}{p_end}
{synopt:{opt maxover:rep(#)}}porcentaje # m{c a'}ximo de curules que puede tener un partido con respecto a su porcentaje de votaci{c o'}n nacional emitida; 
default es {cmd:maxoverrep(.08)}{p_end}
{synopt:{opt maxi:ter(#)}}n{c u'}mero # m{c a'}ximo de iteraciones en la asignaci{c o'}n de curules plurinominales cuando alg{c u'}n partido se encuentra en los supuestos de sobrerrepresentaci{c o'}n;
default es {cmd:maxiter(20)}{p_end}
{synopt:{opt noprint}}sumprime la tabla de resultados{p_end}
{synoptline}
{p2colreset}{...}
{p 4 6 2}
* {opt percrp()} es obligatorio para {cmd:asignadipi}.
{p_end}


{title:Description}

{pstd}
{cmd:asignadip} calcula la composici{c o'}n partidista de la C{c a'}mara de Diputados en M{c e'}xico con los porcentajes de votos de los partidos y/o coaliciones en {varlist}.
A menos que se especifique lo contrario (ver opci{c o'}n {opt nummay()}), las curules uninominales se asignan por el m{c e'}todo de mayor{c i'}a relativa. 
Cada observaci{c o'}n en la base de datos debe representar un distrito electoral.
La asignaci{c o'}n de curules plurinominales se realiza con el m{c e'}todo de resto mayor.
{cmd:asignadip} est{c a'} dise{c n~}ado principalmente para programadores que desean extraer cantidades de inter{c e'}s relacionadas con la C{c a'}mara de Diputados a trav{c e'}s de simulaciones de Monte Carlo 
(v{c e'}anse {helpb estimadip} y {helpb simuladip}). 
Sin embargo, tambi{c e'}n puede utilizarse para elaborar contrafactuales sin necesidad de que {varlist} sea producto de alg{c u'}n procedimiento de simulaci{c o'}n estadistica.
Las opciones de {cmd:asignadip} son lo suficientemente flexibles como para calcular la composici{c o'}n de la C{c a'}mara bajo un amplio rango de reglas electorales.
Por default, las opciones de {cmd: asignadip} corresponden al m{c e'}todo de asignaci{c o'}n utilizado en M{c e'}xico en las elecciones federales de 1997 a 2009.

{pstd}
Los resultados del procedimiento son accesibles para programadores a traves de {cmd:r()}. V{c e'}ase {helpb return}.

{pstd}
{cmd:asignadipi} es la forma inmediata de {cmd:asignadip} (ver {helpb immed}). 


{title:Options for asignadip and asignadipi}

{dlgtab:Main}

{phang}
{opt nuloynoreg(vars)} variable(s) que contienen los porcentajes de votos nulos y para candidatos no registrados. 
Los porcentajes en {varlist} deben sumar 1 en cada observaci{c o'}n, o deben sumar 1 incluyendo los porcentajes en {opt nuloynoreg(vars)}. 
El numero m{c a'}ximo de variables permitidas en {it:vars} es 2.

{phang}
{opt threshold(#)} indica el umbral # m{c i'}nimo de representaci{c o'}n para tener derecho a participar en la asignaci{c o'}n de curules plurinominales; 
default es {cmd:threshold(.02)}.

{phang}
{opt escrp(#)} indica el n{c u'}mero {it:#} de curules plurinominales a repartirse en el componente de representaci{c o'}n proporcional; 
default es {cmd:escrp(200)}.

{phang}
{opt nomay} suprime el componente de mayor{c i'}a relativa en la asignaci{c o'}n de curules; 
es decir, no se asignan diputados uninominales.
Cuando se especifica {cmd:nomay()},
las opciones {opt nummay()},
{opt maxseats()} y {opt maxoverrep()} son ignoradas.

{phang}
{opt norp} suprime el componente de representaci{c o'}n proporcional en la asignaci{c o'}n de curules; es decir, no se asignan diputados plurinominales.
Cuando se especifica {cmd:norp()},
las opciones {opt threshold()}, 
{opt escrp()},
{opt maxseats()} y {opt maxoverrep()} son ignoradas.

{phang}
{opt noprint} sumprime la tabla de resultados.

{dlgtab:Advanced}

{phang}
{opt maxseats(#)} n{c u'}mero # m{c a'}ximo de curules en la C{c a'}mara de Diputados a los que pueden tener derecho los partidos pol{c i'}ticos.
Por ejemplo, si {cmd:maxseats(200)}, 
ning{c u'}n partido puede tener m{c a'}s de 200 esca{c n~}os.
Para especificar que no existen l{c i'}mites al n{c u'}mero de curules,
# debe ser igual n{c u'}mero total de curules en la C{c a'}mara.
Por default, {cmd:maxseats(300)}.

{phang}
{opt maxoverrep(#)} porcentaje # m{c a'}ximo de curules que puede tener un partido con respecto a su 
porcentaje de votaci{c o'}n nacional emitida. 
La votaci{c o'}n nacional emitida es igual a la votaci{c o'}n total emitida menos el porcentaje de 
votos de los partidos que no alcanzan el umbral de representaci{c o'}n, 
los votos nulos, 
y los votos para candidatos no registrados. 
{cmd:maxoverrep()} es ignorado cuando el partido excede en # su porcentaje de votaci{c o'}n nacional 
emitida a causa de sus triunfos en los distritos uninominales.
Para especificar que no existen l{c i'}mites al n{c u'}mero de curules,
# debe ser igual a 1.
Por default, {cmd:maxoverrep(.08)}.

{phang}
{opth nummay(numlist)} instruye a {cmd:asignadip} para que utilice {it: numlist} como el n{c u'}mero de curules de mayor{c i'}a relativa para cada partido en {varlist} o {it: namelist}, 
en lugar de calcularlos a partir de la base de datos.
Esta opci{c o'}n es {c u'}ti para la asignaci{c o'}n de curules a los miembros de una coalici{c o'}n con las reglas vigentes en la elecci{c o'}n federal de 2009.

{phang}
{opth percrp(numlist)} indica el porcentaje de votaci{c o'}n de cada partido en {it: namelist} que debe utilizarse para la asignaci{c o'}n de diputados plurinominales.

{phang}
{opt maxiter(#)} n{c u'}mero # m{c a'}ximo de iteraciones en la asignaci{c o'}n de curules plurinominales cuando alg{c u'}n partido se encuentra en los supuestos de sobrerrepresentaci{c o'}n;
default es {cmd:maxiter(20)}.


{title:Examples}

{phang}Asignaci{c o'}n de curules con opciones por default:

{p 8 10 2}{cmd:. asignadip partido1 partido2 partido3 partido4, nulosynoreg(nulos noreg)}

{phang}Asignaci{c o'}n con otras opciones:

{p 8 10 2}{cmd:. asignadip partido1 partido2 partido3 partido4, nulosynoreg(nulosynoreg) thr(.05)}

{p 8 10 2}{cmd:. asignadip partido1 partido2 partido3 partido4, maxseats(200) maxoverrep(.05)}

{p 8 10 2}{cmd:. asignadip partido1 partido2 partido3 partido4, nomay escrp(500)}

{p 8 10 2}{cmd:. by circunscripcion: asignadip partido1 partido2 partido3 partido4, nomay escrp(100)}

{phang}Asignaci{c o'}n a coaliciones con reglas vigentes en 2009:

{p 8 10 2}{cmd:. asignadip partido1 partido2 coalicion3 coalicion4, norp}

{p 8 10 2}{cmd:. asignadip partido1 partido2 partido3 partido4, nummay( `r(ssd)' )}

{phang}Asignaci{c o'}n de curules con base de datos generada por {helpb simuladip}:

{p 8 10 2}{cmd:. use myfile, clear}{p_end}
{p 8 10 2}{cmd:. {help forvalues} i = 1/1000 {c -(}}{p_end}
{p 8 10 2}{cmd:.{space 5}asignadip partido1 partido2 partido3 partido4 if _IDsim == `i', thr(.05)}{p_end}
{p 8 10 2}{cmd:. {c )-}}


{title:Saved results}

{phang}
{cmd: asignadip} guarda los siguientes resultados en {cmd: r()}:

{synoptset 15 tabbed}{...}
{dlgtab:Scalars}

{synopt:{bf: r(ssd_{it:j})}}curules uninominales para el partido {it:j}{p_end}

{synopt:{bf: r(list_{it:j})}}curules plurinominales para el partido {it:j}{p_end}

{dlgtab:Macros}

{synopt:{bf: r(ssd)}}lista con el n{c u'}mero de curules uninominales para cada partido{p_end}

{synopt:{bf: r(MaxSeats_{it:j})}}indica si el partido {it:j} se encontr{c o'} en los supuestos de sobrerrepresentaci{c o'}n especificados en {opt maxseats()}{p_end}

{synopt:{bf: r(MaxOverr_{it:j})}}indica si el partido {it:j} se encontr{c o'} en los supuestos de sobrerrepresentaci{c o'}n especificados en {opt maxoverrep()}{p_end}

{title:Authors}

{phang}
Javier Aparicio, 
Centro de Investigaci{c o'}n y Docencia Econ{c o'}micas, 
CIDE.
javier.aparicio@cide.edu

{phang}
Javier M{c a'}rquez,
Buend{c i'}a & Laredo.
javier.marquez@buendiaylaredo.com


{title:Reference}

{pstd}
{cmd: asignadip} es parte del paquete {cmd: camaradip}: 
M{c o'}dulo de Stata para elaborar contrafactuales de la C{c a'}mara de Diputados con simulaciones de Monte Carlo.
Si utiliza {cmd: asignadip}, 
por favor cite las siguientes referencias:

{phang}
M{c a'}rquez, Javier y Javier Aparicio (2010), Un modelo Monte Carlo para la C{c a'}mara de Diputados en M{c e'}xico, Pol’tica y Gobierno, vol. XVII, n{c u'}m 2.

{phang}
---- (2009), {cmd: camaradip}: M{c o'}dulo de Stata para elaborar contrafactuales de la C{c a'}mara de Diputados con simulaciones de Monte Carlo.


{title:Also see}

{pstd}
Online: {helpb estimadip}, {helpb simuladip}, {helpb forvalues}.