log using dia2cursoencup.txt, text replace // crea una "bitacora" con la salida de stata

use "C:\Users\Javier\Documents\ENCUP_2008stata.dta", clear

** CURSO ENCUP / Javier Aparicio
** DIA 2 (27 jul 2009) 
**
** Creación y recodificación de variables (generate, recode, label var)
** Prueba Chi cuadrada para tablas de contingencia
** Modelos logit para variables dependientes binarias
** Modelos oprobit para variables dependientes ordinales
**

// Nota: Todo lo que aparece a la derecha de "//"  o "*" es un comentario


**  Explorando los datos 
desc  ent - p6r  // describe desde la variable ent hasta p6r
summ  ent - p6r


** Generando variables "de trabajo" para no contaminar las originales

gen democ = p2            // democ es un "clon" de p2
recode democ 1=1 2=0 9=.  // recodifico democ para que sea binaria 0/1

gen satisfdem = p3      // satisfdem es un clon de p3

* etiqueta de variables
label var democ "mexico es democ? 1=si 0=no"
label values democ p2   // etiqueta de valores
label var satisfdem "satisfecho c/dem? 1=muy 2=algo ... 4=nada"
label values satisfdem p3  // etiqueta de valores

tab democ p2
tab democ p2, nolabel   // verificando "clonacion"

tab satisfdem  p3
tab satisfdem p3, nolabel  // verificando "clonacion"

* Recodificando la variable sex
generate mujer = sex==2  // 1 si sex==2, 0 en caso contrario
tab mujer
label var mujer "1=mujer, 0=hombre"

* Recodificando confianza en la iglesia (p6h)
tab p6h    
tab p6h, nolab   // noten que la escala es de "desconfianza"

gen configle = -p6h   // ahora va de -4 a -1
tab configle

replace configle = . if p6h == 9  // elimino los NS/NC

label var configle "confianza en iglesia -4=nada ... -1=mucha"
tab configle
hist configle

* Recodificando el nivel de educacion (i_niv)
tab i_niv, miss
tab i_niv, nolabel  // hay muchas categorias...

** Para simplificar el análisis, generamos 
** una "dummy" para quienes tienen "prepa o más"
generate prepaomas = i_niv >= 4   // 1=si i_niv es mayor o igual a 4, 0 en caso contrario
replace prepa = . if i_niv==99   // elimino los NS/NC

label var prepaomas "1=estudio prepa o mas, 0=sin prepa"
tab i_niv prepaomas , miss  // verifico que la nueva variable esté bien

tab ing    // es una variable continua!
histogram ing  // la grafica indica gran sesgo positivo

* Transformando ingreso en log(ingreso) para "normalizarla" un poco
generate loging = log(ing)
label var loging "log(ingreso)"
histogram loging   // ahora "se ve" mucho mejor!


* Creando algunas variables "interactivas"
gen edaing = eda * ing   // controla por "rucos ricos vs. jovenes pobres"
gen edamujer = eda * mujer  // controla por "abuelitas vs. chicas"

* Vale la pena "subir" mis nuevas variables al inicio de la base:
order democ - edamujer

* Guardo la base modificada con un NUEVO nombre (para no contaminar la original)
save encupmodificada, replace


************ ANALISIS *************

tab democ
tab eda
tab eda democ, chi
tab eda democ, row chi

scatter democ eda   // scatterplot entre democ y edad
scatter democ eda, jitter(5)   // scatterplot "agitado"

scatter democ eda || lfit democ eda  // scatterplot + regresion simple
scatter democ eda, jitter(5) || lfit democ eda

reg democ eda    // regresion lineal SIMPLE
logit democ eda  // modelo LOGIT simple

** La prueba chi cuadrada ayuda a explorar "relaciones de pares"
tab democ mujer , row chi
tab democ prepaomas , row chi
** pero si hay muchas categorias es complicado:
tab eda democ , row chi

** Un modelo LOGIT multiple puede estimar "al mismo tiempo" el efecto 
** de edad y género en la confianza en la democracia...

logit democ eda  mujer  // añado una 2a variable p/controlar por género
logit democ eda  mujer prepaomas // añado una 3a var p/controlar educacion
logit democ eda  mujer prepaomas ing // añado ingreso...
logit democ eda  mujer prepaomas loging  // añado log(ingreso)

* Noten como los coeficientes estimados, y su significancia, "cambian" conforme 
* añado o ignoro variables: esto es el "sesgo de variable omitida"

scatter eda loging
corr eda loging   // edad e ingreso no tienen una alta correlacion


** Probando "efectos interactivos"

logit democ eda  mujer prepaomas  // modelo sin interacciones

* controlando por la interaccion entre edad y genero
logit democ eda  mujer prepaomas edamujer  

* controlando por la interaccion entre edad e ingreso 
logit democ eda  mujer prepaomas loging edaing



*** MODELOS OLOGIT para VARIABLES ORDINALES

** La "confianza en la iglesia" va de -4 nada, -3 poca ... a -1 (mucha)

tab prepaomas configle, row chi  
* la chi cuadrada me dice que educacion y confianza en la iglesia 
* NO son independientes

tab mujer configle, row chi
* la chi cuadrada me dice que genero y confianza en la iglesia 
* NO son independientes

** Pero podemos estimar conjuntamente el efecto 
** de estas variables en la confianza en la iglesia:

ologit configle prepaomas loging
ologit configle prepaomas loging mujer
ologit configle prepaomas loging eda mujer

* A partir del último modelo, ¿qué variables explican mejor 
* la confianza en la iglesia?
***
* A mayor educación o ingreso, menor confianza
* En general, las mujeres confian más en la iglesia que los hombres
* La edad no parece afectar la confianza en la iglesia

* listo! ahora solo hay que cerrar la bitacora

log close