log using dia3cursoencup.txt, text replace // crea una "bitacora" con la salida de stata

** CURSO ENCUP / Javier Aparicio
** DIA 3 (28 jul 2009) 
**
** Creación y recodificación de variables (generate, recode, label var)
** Prueba Chi cuadrada para tablas de contingencia
** Modelos mlogit para variables dependientes categóricas no ordenadas
** Probabilidades predichas (comados "extra" Spost: prtab, prvalue)

// Nota: Todo lo que aparece a la derecha de "//"  o "*" es un comentario


use "C:\Users\Javier\Documents\encupmodificada.dta", clear


** Analizando una pregunta categórica no ordenada (o multinomial)

tab p23   // 23. en su opinión, ¿nuestro país necesita mejores políticos, mejores leyes o ambas?
gen mejor= p23   // genero clon de pregunta 23

label values mejor p23  // etiqueto los valores del clon igual que p23

tab mejor
tab mejor, nolab miss
replace mejor = . if p23 == 9  // elimino NS/NC

tab mejor, nolab miss

* Creando indicadores binarios para comerciantes y profesionistas
tab ocu,
tab ocu, nolab

gen comerciante = ocu == 4   // dummy para comerciantes
gen profesionista = ocu == 1  // dummy para profesionistas

label var comerciante "=1 si ocu=4, 0 si no"
label var profesionista "=1 si ocu=1, 0 si no"

tab comerciante
tab profes

order mejor profes comercia  // subo estas variables al inicio de la base

save encupmodificada2, replace  // (guardamos los cambios en la base)


* Analizando preferencias por mejores politicos o mejores leyes

hist mejor
tab mejor
tab mejor, nolabel   // tabulacion simple sin etiquetas (necesitamos 1 mejores politicos, 2 leyes, 3 ambos)
tab mujer mejor, chi row      // ...por género
tab prepaomas mejor, chi row  // ...por estudios de prepa o más
tab democ mejor, chi row      // ...por si cree que somos democracia
tab satisf mejor if satisf < 9 , chi row  // ...por satisfaccion con la democracia
tab configle mejor , chi row   // ...por confianza en la iglesia

* Podemos correr una regresión múltiple

reg  mejor eda loging mujer prepa

** ...pero esto sería incorrecto pues la variable dependiente NO es continua NI ordenada.
** es preferible estimar un 
**
** Modelo LOGITSICO MULTINOMIAL (mlogit)

mlogit mejor  eda loging mujer prepa democ profe comerc
mlogit mejor  eda loging mujer prepa democ profe comerc
mlogit mejor  eda loging mujer prepa democ profe comerc if mejor < 3  // excluyendo la 3a categoria

** ... es equivalente a un LOGIT donde la 1a categoria es la variable dependiente:
generate mejpol = mejor ==1
logit mejpol eda loging mujer prepa democ profe comerc if mejor < 3

** pero si incluyo los casos de la 3a categoria ya no es igual:
logit mejpol eda loging mujer prepa democ profe comerc

** Un modelo NO restringido (que no omite variables explicativas)
mlogit mejor eda loging mujer prepa democ profe comerc

** Un modelo restringido (omite algunas variables, como loging y edad)
mlogit mejor mujer prepa democ profe

** La salida del modelo me indica el signo y significancia de las variables
** explicativas.  Pero, al ser un modelo NO LINEAL, no podemos interpretar 
** directamente la MAGNITUD de los efectos estimados, ni los cambios
** en las "probabilidades predichas" por el modelo.


** Algunos comandos ayudan a interpretar los modelos como este:

tab mejor  // estas son las frecuencias observadas

mlogit mejor mujer prepa democ profe, nolog

** Probabilidades predichas para hombres/mujeres vs. con/sin estudios de prepa o más:
prtab  mujer prepa   
  ** La última tabla indica que: 
  ** Hombres sin prepa tienen 36.28% de probabilidad de opinar que necesitamos mejores políticos
  ** En cambio, mujeres con prepa o más tienen un 45.99% de probabilidad de opinar eso mismo

** Probabilidades predichas para quienes creen que SI/NO tenemos una democracia vs. 
** con/sin estudios de prepa o más:
prtab demo prepaomas

** Predicciones para mujeres con prepa o más y que creen que tenemos una democracia:
prvalue, x(democ 1 mujer 1 prepa 1)
  ** Estas personas tienen 32% de probabilidad de preferir mejores politicos, 22% ambas cosas, 
  ** y 46% mejores políticos (ésta es la predicción más probable)

** Predicciones para mujeres profesionistas con prepa o más, y que creen que tenemos una democracia:
prvalue, x(democ 1 mujer 1 prepa 1 profes 1)
  ** Estas personas tienen 26.4% de probabilidad de preferir mejores politicos, 25.8% ambas cosas,
  ** y 47.8% mejores políticos. 

** Predicciones para hombres profesionistas con prepa o más, y que creen que tenemos una democracia:
prvalue, x(democ 1 mujer 0 prepa 1 profes 1)

** Predicciones para hombres NO profesionistas con prepa o más, y que creen que tenemos una democracia:
prvalue, x(democ 1 mujer 0 prepa 1 profes 0)

** Predicciones para hombres NO profesionistas SIN prepa, y que creen que tenemos una democracia:
prvalue, x(democ 1 mujer 0 prepa 0 profes 0)

** con esto concluimos el ejercicio y nuestro curso!

** cerramos la bitácora

log close